apply plugin: 'java'

/** the name of the plugin zip file */
archivesBaseName = 'taskplanner.logaction'

/** the location/repository of the needed jar files */
if ( repositories.size() == 0 ) {
	repositories {    
	    maven { url 'https://maven.inetsoftware.de/release/'
	    	content { includeGroup 'de.inetsoftware' }
	    }
	    maven { url 'https://maven.inetsoftware.de/beta/'
	    	content { includeGroup 'de.inetsoftware' }
	    }
	
	    mavenCentral()
	}
}

/** the needed jar files */
dependencies {
    implementation 'de.inetsoftware:inetcore:+', 'de.inetsoftware:taskplanner:+'
}

sourceSets {
    main {
        java {
            srcDirs = ['src']
        }
        resources {
            srcDirs = ['src']
            include '**/*.png'
            include '**/*.js'
            include '**/*.html'
            include '**/*.css'
            include '**/*.less'
            include '**/*.properties'
        }
    }
}

/**
 * Package the plugin
 */
task createPlugin(dependsOn: 'jar', type: Zip) {
	group = 'build'
    description 'Create the plugin zip file'
    assemble.dependsOn it
    from jar
    from fileTree( '.' ) {
    	include 'plugin.properties'
    	include 'plugin.properties.d/**'
    }
}

defaultTasks 'clean', 'createPlugin'